group 'nl.astraeus'
version '1.6.2-SNAPSHOT'

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'maven'
apply plugin: 'maven-publish'

sourceSets {
    main.java.srcDirs += 'src'
    main.resources.srcDirs += 'src'

    test.java.srcDirs += 'test'
    test.resources.srcDirs += 'test'
}

sourceCompatibility = 1.6
targetCompatibility = 1.6

repositories {
    maven {
        url "http://nexus.astraeus.nl/nexus/content/groups/public"
    }
}

ext {
    PUBLISH_GROUP_ID = group
    PUBLISH_VERSION = version
    PUBLISH_ARTIFACT_ID = name
}

apply from: "${rootProject.projectDir}/scripts/publish-mavencentral.gradle"

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'

    testCompile "com.h2database:h2:1.4.+"

    compile "com.samskivert:jmustache:1.15"
    compile "org.nanohttpd:nanohttpd:2.2.0"

    configurations.compile.exclude module: 'javax.servlet-api'
}

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "http://nexus.astraeus.nl/nexus/content/repositories/releases") {
                authentication(userName: nexusUsername, password: nexusPassword)
            }
            snapshotRepository(url: "http://nexus.astraeus.nl/nexus/content/repositories/snapshots") {
                authentication(userName: nexusUsername, password: nexusPassword)
            }
        }
    }
}

javadoc {
    failOnError = false
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }
}

jar {
    from {
        configurations.compile.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
}

task fatJar(type: Jar) {
    manifest {
        attributes 'Implementation-Title': 'simple-jdbc-statistics',
                'Implementation-Version': version
    }
    baseName = project.name + '-nodep'
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}